b0 0.0.0 · OCaml Package

Command lines.

Command line values specify the command line arguments given to tools spawns. In certain contexts the command line value is the full specification of the tool spawn, in this case the first element of the line defines the program to invoke. In other contexts the tool to invoke and its arguments are kept separate.

examples.

B0 artefact. This module allows to shield command arguments. Shielded arguments have no special semantics as far as the command line is concerned they simply indicate that the argument value itself does not influence the file outputs of the tool. As such shielded arguments do not appear in the command line signature which is used to memoize tool spawns. A typical example of shielded argument are file paths to inputs: it's often the file contents not the actual file path that determines the tool output; beware though that some tool use both the file path contents and the actual file path in their outputs.

Command lines

type t

The type for command lines. A command line is a list of command line arguments.

val is_empty : t -> bool

is_empty l is true iff l is an empty list of arguments.

val empty : t

empty is an empty list of arguments.

val arg : string -> t

arg a is the argument a.

val append : t -> t -> t

append l1 l2 appends arguments l2 to l1.

val shield : t -> t

shield l indicates that arguments l do not influence the tool's invocation outputs. These arguments are omitted from the command line's signature.

Derived combinators

val (%) : t -> string -> t

l % a is append l (arg a).

val (%%) : t -> t -> t

l1 % l2 is append l1 l2.

val if' : bool -> t -> t

if' cond l is l if cond is true and empty otherwise.

val path : Fpath.t -> t

path p is arg (Fpath.to_string p).

val spath : Fpath.t -> t

spath p is shield (path p).

val args : ?slip:string -> string list -> t

args ?slip l is a command line from the list of arguments l. If slip is specified it is added on the command line before each element of l.

val rev_args : ?slip:string -> string list -> t

rev_args ?slip l is args ?slip (List.rev l).

val of_list : ?slip:string -> ('a -> string) -> 'a list -> t

of_list ?slip conv l is args ?slip (List.map conv l).

val of_rev_list : ?slip:string -> ('a -> string) -> 'a list -> t

of_rev_list ?slip conv l is args ?slip (List.rev_map conv l).

val paths : ?slip:string -> Fpath.t list -> t

paths ?slip ps is of_list ?slip Fpath.to_string ps.

val rev_paths : ?slip:string -> Fpath.t list -> t

rev_paths ?slip ps is of_rev_list ?slip Fpath.to_string ps.

Tools

type tool = Fpath.t

The type for command line tools. A command line tool is represented by a file path according to the POSIX convention for exec(3). If it is made of a single segment, for example Fpath.v "ocaml", it represents a program name to be looked up via a search procedure; for example in the PATH environment variable. If it is a file path with multiple segments (POSIX would say if they contain a slash characters) the program is the file itself.

val tool : t -> tool option

tool l is l's first element. This is None if the line is empty or if the first element can't be parsed to a tool.

val set_tool : tool -> t -> t option

set_tool tool l replaces l's first element with tool. This is None if l is empty.

val get_tool : t -> tool

get_tool is like tool but

raises Invalid_argument
in case of error.

Predicates

val is_singleton : t -> bool

is_singleton l is true iff l has a single argument.

Converting

val to_list : t -> string list

to_list l converts l to a list of strings.

val to_sig : t -> string list

to_sig l is the sequence of unshielded arguments.

val to_list_and_sig : t -> string list * string list

to_list_and_sig l is a l as a list of strings tuppled with its signature: the sequence of unshielded arguments.

val to_string : t -> string

to_string l converts l to a string that can be passed to the command(3) POSIX system call.

val of_string : string -> (t, string) result

of_string s tokenizes s into a command line. The tokens are recognized according to the token production of the following grammar which should be mostly be compatible with POSIX shell tokenization.

white   ::= ' ' | '\t' | '\n' | '\x0B' | '\x0C' | '\r'
squot   ::= '\''
dquot   ::= '\"'
bslash  ::= '\\'
tokens  ::= white+ tokens | token tokens | ϵ
token   ::= ([^squot dquot white] | squoted | dquoted) token | ϵ
squoted ::= squot [^squot]* squot
dquoted ::= dquot (qchar | [^dquot])* dquot
qchar   ::= bslash (bslash | dquot | '$' | '`' | '\n')

qchar are substitued by the byte they escape except for '\n' which removes the backslash and newline from the byte stream. squoted and dquoted represent the bytes they enclose.

val conv : t Conv.t

conv converts command lines.

val pp : t Fmt.t

pp ppf l formats an unspecified representation of l on ppf.

val dump : t Fmt.t

dump ppf l dumps and unspecified representation of l on ppf.

Examples

let ls p = Cmd.(arg "ls" % "-a" % path p)
let tar archive dir =
  Cmd.(arg "tar" % "-cvf" %% shield (path archive) %% path dir)

let opam cmd = Cmd.(arg "opam" % cmd)
let opam_install pkgs = Cmd.(opam "install" %% args pkgs)

let ocamlc ?(debug = false) file =
  Cmd.(arg "ocamlc" % "-c" % if' debug (arg "-g") %% path file)

let ocamlopt ?(profile = false) ?(debug = false) incs file =
  let profile = Cmd.(if' profile (arg "-p")) in
  let debug = Cmd.(if' debug (arg "-g")) in
  let incs = Cmd.(shield (paths ~slip:"-I" incs)) in
  Cmd.(arg "ocamlopt" % "-c" %% debug %% profile %% incs %% shield (path file))